@echo off

rem パラメタ %1: YYYYMMDD または YYYY/MM/DD 日付

rem パラメタ %2: -d  -m 差分区分(-d:日数 -m:月数)

rem パラメタ %3: 差分数

rem 返り値 %YYYYMMDD%, %days% 計算後の文字列日付と通算日数

rem

rem 西暦1600月3月1日を基点に日数計算

rem 1年は3月から始まり2月で終わることとする

rem --------------------------------------------------

rem 　　3　 4　 5　 6　 7　 8　 9　10　11　12　01　02月　　月号

rem 　　0　 1　 2　 3　 4　 5　 6　 7　 8　 9　10　11月　　新月号

rem 　 31　30　31　30　31　31　30　31　30　31　31　28

rem 　  0　31　61　92 122 153 184 214 245 275 306 337　　　年頭からの通算日

rem --------------------------------------------------



setlocal EnableDelayedExpansion

set days_table=312831303130313130313031

set YYYYMMDD=%1

set YYYYMMDD=%YYYYMMDD:/=%

set YY=%YYYYMMDD:~0,4%

set MM=%YYYYMMDD:~4,2%

set DD=%YYYYMMDD:~6%

if "%MM:~0,1%"=="0" set MM=%MM:~1%

if "%DD:~0,1%"=="0" set DD=%DD:~1%



if "%2" equ "-d" (

call :ADtoTD

set /a days = !days! + %3

call :TDtoAD !days!

goto :end

)



if "%2" neq "-m" (

call :ADtoTD

goto :end

)



set /a Y1 = %3 / 12

set /a Y2 = %3 %% 12

set /a YY += Y1

set /a MM += Y2

if %MM% LEQ 0 set /a YY -= 1, MM += 12

if %MM% GTR 12 set /a YY += 1, MM -= 12

set /a mon = (MM - 1) * 2

set max=!days_table:~%mon%,2!

if %MM%==2 (

set /a mod4 = %YY% %% 4

set /a mod100 = %YY% %% 100

set /a mod400 = %YY% %% 400

if !mod4! neq 0 goto xxx

if !mod400! equ 0 set /a max += 1 & goto xxx

if !mod100! equ 0 goto xxx

set /a max += 1

)

:xxx

if %DD% GTR %max% set DD=%max%

set MM=0%MM%

set MM=%MM:~-2%

set DD=0%DD%

set DD=%DD:~-2%

set YYYYMMDD=%YY%%MM%%DD%

if "%MM:~0,1%"=="0" set MM=%MM:~1%

if "%DD:~0,1%"=="0" set DD=%DD:~1%

call :ADtoTD



:end

endlocal & set YYYYMMDD=%YYYYMMDD% & set days=%days%

echo %YYYYMMDD%

goto :eof



rem -----------------------------

rem 西暦を通算日に変換する

rem -----------------------------

:ADtoTD

set totaldays_table= 00 31 61 92122153184214245275306337

set /a YY = YY - 1600

if %MM% LEQ 2 set /a YY -= 1

set /a MM = (MM + 9) %% 12



set /a days = YY * 365 + (YY / 4) - (YY / 100) + (YY / 400)

set /a mon = MM * 3

set /a days += !totaldays_table:~%mon%,3! + %DD% - 1

endlocal & set days=%days%

goto :eof



rem -----------------------------

rem 通算日を西暦に変換する

rem -----------------------------

:TDtoAD

set days=%1

set /a d1 = days / 146097

set /a a1 = days %% 146097

set /a d2 = a1 / 36524

set /a a2 = a1 %% 36524

if %d2% equ 4 set /a d2 -= 1, a2 += 36524

set /a d3 = a2 / 1461

set /a a3 = a2 %% 1461

set /a d4 = a3 / 365

set /a a4 = a3 %% 365

if %d4% equ 4 set /a d4 -= 1, a4 += 365

set /a d5 = a4 / 153

set /a a5 = a4 %% 153

set /a d6 = a5 / 61

set /a a6 = a5 %% 61

set /a d7 = a6 / 31

set /a a7 = a6 %% 31



set /a YY = 400*d1 + 100*d2 + 4*d3 + d4 + 1600

set /a MM = 5*d5 + 2*d6 + d7 + 3

set /a DD = a7 + 1

if %MM% GTR 12 set /a MM -= 12 , YY += 1

set MM=0%MM%

set MM=%MM:~-2%

set DD=0%DD%

set DD=%DD:~-2%

endlocal & set YYYYMMDD=%YY%%MM%%DD%

goto :eof