最近、ようやく動画の音声として、MP3から離れるようになってきました。
　別にMP3で不満な点は無かったんですが、巷の噂でAACの方が音質が良いと
謂われてたりして気にはなってたんです。
　またmkvコンテナの使用にも抵抗感が無くなって来ており、丁度良い機会かと
思い、Nero 6のAACエンコーダを使ってみました。
　GUIツールとして、Encode Audio FilesとかNero Wave Editorとかからも
WAVファイルをAACエンコードすることは出来ますが、ちょっと使い難い面もあり
ます。
　そこで今回はfreeなコマンドラインツールであるaacenc32を使うことに
しました。
　でもファイル名に日本語等を使うような場合、コマンドラインから指定するの
が大変なので、この点をバッチファイルで補なってみます。

　前置きが長くなりましたが、ここではそのコマンドファイルを紹介しよう
と思います。


----- AACenc.cmd -----

@echo off

setlocal EnableDelayedExpansion

rem *** dstdirに出力先を設定する。設定しない場合はsrcと同じフォルダとなる ***

rem set dstdir=%temp%

rem ----------------------------

set dstdir=

set default=-vbr normal

set aacencdir=%SystemDrive%\bin\sound\Nero Frontends

rem *************************************************************************



if "%~1" == "" goto usage

set n=1

:num_param_chk

if "%~2" neq "" (set p!n!=%~1& shift& set /a n=n+1& goto num_param_chk)

set vbr=

set apend=

if %n% == 1 (

    set vbr=%default%

) else (

    if "%p1%" equ "160"  (set vbr=-cbr %p1%)

    if "%p1%" equ "128"  (set vbr=-cbr %p1%)

rem ***   if "%p1%" geq "16"  (

rem ***       if "%p1%" equ "448" (set vbr=-cbr %p1%)

rem ***   )

  if "!vbr!" == ""  (set vbr=-vbr %p1%)

  set apend=_%p1%

)

set /a n_1=%n%-1

set opt=

for /l %%i in (2,1,%n_1%) do (set opt=!opt! !p%%i!)

set src=%~f1

if "%~x1" == "" (set src=%~dpn1.wav)

if not defined dstdir (set dstdir=%~dp1)

if %dstdir:~-1% neq \ (set dstdir=%dstdir%\)

set dst=%dstdir%%~n1%apend%.mp4



:execute

set path=%CommonProgramFiles%\Ahead\AudioPlugins;%path%

pushd %aacencdir%

aacenc32 %vbr% %opt% "%src%" "%dst%"

popd

goto end



:usage

echo.

echo usage : %0 [vbr [opt-list...]] wavfile

echo           vbr      : 128 ^| 160

echo                        ^| internet ^| streaming ^| normal

echo                        ^| extream ^| audiophile ^| transcoding

echo                      (default normal)

echo           opt-list : others parameter-list

echo           wavfile  : [drv:\][path]filename[.ext]

echo.



:end

pause

endlocal

設定ポイント
・dstdirには、出力先を指定する。（例　set dstdir=%temp%）
　指定しない場合はソースと同じ場所に出力されます。
・Nero Frontendは、
　　%SystemDrive%\bin\sound\Nero Frontends
　に置いてあります。（各自、自分の格納場所に変更してください）


さて使い方ですが、
1. コマンドラインから使う場合は、上記コマンドファイルをパスが通ったところ
　に置いておき、
　　>aacenc foo
とタイプすると、foo.wavからfoo.mp4が作成されます。

2. エクスプローラから使う場合は、上記コマンドファイルに対するリンクを作成
　します。
　・SendToフォルダ内に作成すると、右クリックの「送る」メニューが使えます。
　・デスクトップ上に作成し、ドラッグドロップすることもできます。

【私見】
　ここまで読んで、こんな機能ならそのままaacenc32を呼んでも変わりはないん
　ではないかな？というような感想を持った人もいるとは思います。
　確かにその通りなのですが、ファイル拡張子を.mp4にするとか、出力フォルダ
　を変えたいという欲求でのみ作成したものです。

　また、Windows2000/XPで拡張されたコンソールコマンドの使用例として
　参考になる要素もいくつか含まれているのでムダにはならないと思っています。

この記事のトラックバックURL：
http://tb.plaza.rakuten.co.jp/kiraru2002/diary/200507300000/e7a73/